Próbuję wstawić nazwę użytkownika, gdy określona wartość jest wypełniona do komórki.

Przykład,

Jeśli komórka X14 jest ustawiona na "Gotowe" lub "Pomiń" przez użytkownika, a następnie chcę komórki Z14 mieć nazwę użytkownika, który obecnie pracuje w skoroszycie. A kiedy komórka nie ma już "wykonywania" ani "pomiń", Nazwa użytkownika też znika.

Czy ktoś z ciebie może mi pomóc? Korzystnie tylko formuła Excel, ale VBA jest również dobra.

Dziękuję Ci !

-1
Sunghwan Park 22 luty 2019, 05:00

2 odpowiedzi

Najlepsza odpowiedź

Użyj poniższej, jeśli szukasz zmiany dla dowolnej komórki na {x0}} (, który jest Target.Column = 24 ) ...

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Column = 24 And Target.Count = 1 Then
    If Target = "Done" Or Target = "Skip" Then
        Application.EnableEvents = False
            Target.Offset(0, 2) = Application.UserName
        Application.EnableEvents = True
    End If
End If

End Sub
1
urdearboy 22 luty 2019, 02:43

Jako scenariusz wydaje się, że moim zdaniem możesz mieć więcej niż jednego użytkownika, że podejście VBA jest trasa, którą należy podjąć.

Skopiuj i wklej ten kod do modułu arkuszy i dostosuj <<< Dostosuj to >>>

Private Sub Worksheet_Change(ByVal Target As Range)

    ' Define object variables
    Dim statusRange As Range
    Dim changedCell As Range

    ' Define variables
    Dim currentUserName As String
    Dim userNameColumn As String
    Dim statusColumnNumber As Integer
    Dim statusValuesList As Variant

    ' <<< Customize this >>>
    Set statusRange = Range("X10:X100") ' Limit the cells that will record the status
    statusValuesList = Array("Done", "Skip") ' Add more status values separated by commas and inside quotes (this is not case-sensitive)
    userNameColumn = "Z" ' Column letter where the UserName is going to be stamped

    ' Prevent from firing other events while making changes to cells
    Application.EnableEvents = False

    ' Validate if cell changed belongs to valid column and rows and if it has a valid status
    If Not Intersect(Target, statusRange) Is Nothing Then

        For Each changedCell In Target

            If Not IsError(Application.Match(changedCell.Value, statusValuesList, 0)) Then

                ' Get current username
                currentUserName = Environ("Username")

            Else

                ' Empty username string
                currentUserName = vbNullString

            End If

            ' Assign username to cell in previously defined column and same row
            Range(userNameColumn & changedCell.Row).Value = currentUserName

        Next changedCell

    End If

    ' Reenable firing events
    Application.EnableEvents = True

End Sub
0
Ricardo Diaz 22 luty 2019, 11:25