Muszę połączyć dwa rodzeństwo

<table>
    <tbody>
    <tr>
    <td> table data</td>
    </tr>
    </tbody>
    <tbody>
    <tr>
    <td> table data</td>
    </tr>
    </tbody>
    </table>

Oczekiwany wynik:

<table>
<tbody>
<tr>
<td> table data</td>
</tr>
<tr><td> table data</td>
</tr>
</tbody>
</table>

Mój kod XSLT to:

<xsl:template match="/">
   <xsl:for-each-group select="*" group-adjacent="boolean(self::tbody)">
         <tbody>
    <xsl:value-of select="."/>
         </tbody>
         </xsl:for-each-group>
    </xsl:template>

Który nie daje prawidłowej mocy. Czy mógłbyś zaproponować

0
Richa Bajaj 22 luty 2019, 14:13

2 odpowiedzi

Najlepsza odpowiedź

Twój przykład może być obsługiwany prosto przez:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/table">
    <xsl:copy>
        <tbody>
            <xsl:copy-of select="tbody/*"/>
        </tbody>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>
0
michael.hor257k 22 luty 2019, 12:01

Istnieje wiele problemów z aktualnym XSLT

  1. Twój szablon pasuje do węzła dokumentu, który w przypadku jest rodzicem elementu {x0}}, a nie samego elementu table. Ponieważ próbujesz grupować na elementy {x2}}, Twój szablon powinien pasować do elementu table
  2. xsl:value-of Zwraca tylko wartość tekstową węzła. Należy tutaj używać xsl:copy-of (lub {x2}} w połączeniu z szablonem tożsamości). Należy również wybrać wszystkie elementy w grupie, a nie tylko bieżącym elementem.
  3. Nie rozliczyłeś tego, co dzieje się dla węzłów pod stołem innym niż {x0}}

Więc twój XSLT powinien wyglądać tak ....

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="html" indent="yes" />
  <xsl:strip-space elements="*" />

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="table">
    <table>
      <xsl:for-each-group select="*" group-adjacent="boolean(self::tbody)">
        <xsl:choose>
          <xsl:when test="current-grouping-key()">
            <tbody>
              <xsl:apply-templates select="current-group()/*"/>
            </tbody>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="current-group()" />
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </table>
  </xsl:template>
</xsl:stylesheet>

Uwaga, jeśli używasz XSLT 3.0, możesz zastąpić szablon tożsamości:

<xsl:mode on-no-match="shallow-copy"/>

Z drugiej strony, jeśli w rzeczywistości możesz użyć XSLT 1.0, musisz to zrobić Grupowanie muenchian. Oznacza to, że określanie klucza taka:

<xsl:key name="table" match="table/*" use="boolean(self::tbody)" />

Następnie, zamiast używać xsl:for-each-group, zrób to (chociaż jest to grupa wszystkich elementów tbody, a nie tylko sąsiednie)

<xsl:for-each select="*[generate-id() = generate-id(key('table', boolean(self::tbody))[1])]">

Spróbuj tego XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="html" indent="yes" />
  <xsl:strip-space elements="*" />

  <xsl:key name="table" match="table/*" use="boolean(self::tbody)" />

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="table">
    <table>
      <xsl:for-each select="*[generate-id() = generate-id(key('table', boolean(self::tbody))[1])]">
        <xsl:choose>
          <xsl:when test="self::tbody">
            <tbody>
              <xsl:apply-templates select="key('table', true())/*"/>
            </tbody>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="key('table', false())" />
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>

Oczywiście, po tym wszystkim, odpowiedź Michael.Hor257K jest znacznie prostsza w tym przypadku. (Chociaż zdecydowanie warto przeczytać grupowanie Muenchian, jeśli rzeczywiście utkniesz z XSLT 1.0).

1
Tim C 22 luty 2019, 12:07