Odziedziczyłem następujący kod, który został napisany i pracuje przeciwko typu-tiny-1.004004 :

package Company::Types;

use Type::Library -base, -declare => qw< TruncatedString >;
use Type::Utils -all;

declare TruncatedString, as Str,
    where { length $_ },
    inline_as {
        my ($constraint, $varname) = @_;
        
        return sprintf ( '!defined %s or %s',
            $varname,
            $constraint->parent->inline_check($varname),
        );
    },
    constraint_generator => sub {
        my ($max) = @_;
        die q{Max length must be positive!} unless int($max) > 0;
        return sub { 
            (length $_) <= $max;
        };
    },
    inline_generator => sub {
        my ($max) = @_;
        return sub { 
            my ($constraint, $varname) = @_;

            return sprintf(
                '%s and length %s <= %d', 
                $constraint->parent->inline_check($varname),
                $varname,
                $max,
            );
        };
    },
    coercion_generator => sub {
        my ($base, $derived, $max) = @_;
        # $base - TruncatedString
        # $derived - TruncatedString[<N>]
        # $max - N
        
        # Not sure if I should be adding the coercion to $base or $derived, but I suspect that 
        # $derived is the correct choice here.
        $derived->coercion->add_type_coercions(Str, 
            sub {
                return substr $_, 0, $max;
            }
        );
    };

Jednak nie działa przeciwko typu-tiny-1.012000. Napisałem następujący test, aby zilustrować problem:

use Test2::V0;
use Time::Out qw< timeout >;
use Company::Types qw< TruncatedString >;

subtest 'Coercing to TruncatedString->of(10)' => sub {
    timeout 2 => sub {                      # test hangs without timeout
        my $type = TruncatedString->of(10); # same as TruncatedString[10]
        ok( try_ok { $type->coerce('123456789012') }, 'should not throw an exception' );
    } || bail_out( 'Ran out of time: ' . $@ );
};

done_testing();

Wyprowadza to, co następuje:

# Seeded srand with seed '20201120' from local date.
Deep recursion on subroutine "Type::Tiny::_build_coercion" at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 399.
Deep recursion on anonymous subroutine at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 467.
Deep recursion on anonymous subroutine at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 1015.
not ok 1 - Coercing to TruncatedString->of(10) {
    not ok 1
    # Failed test at t/truncated-string.t line 8.
    # Exception: CODE(0x7fee0fb78998)
    not ok 2 - should not throw an exception
    # Failed test 'should not throw an exception'
    # at t/truncated-string.t line 8.
    1..2
}

# Failed test 'Coercing to TruncatedString->of(10)'
# at t/truncated-string.t line 10.
1..1
Dubious, test returned 1 (wstat 256, 0x100)
Failed 1/1 subtests 

Test Summary Report
-------------------
t/truncated-string.t (Wstat: 256 Tests: 1 Failed: 1)
  Failed test:  1
  Non-zero exit status: 1
Files=1, Tests=1,  4 wallclock secs ( 0.02 usr  0.01 sys +  3.43 cusr  0.38 csys =  3.84 CPU)
Result: FAIL

Zawęziłem problem do coercion_generator (jeśli komentuję to, straciłem ten błąd) i zauważyłem to w Docs:

Następujące atrybuty są używane do sparametryzowanych przymusów, ale nie są w pełni udokumentowane, ponieważ mogą się zmienić w najbliższej przyszłości:

Przypuszczam, że to od tego czasu zmieniło i miał nadzieję na pomoc, jak zaktualizować mój istniejący kod, aby nadrobić zaległości?

5
j1n3l0 20 listopad 2020, 22:04

1 odpowiedź

Najlepsza odpowiedź

Nie jestem pewien, czy powinienem dodać przymus do $ Base lub $ wywodzącej się

Ani. Powinieneś go zwrócić.

coercion_generator => sub {
    my ($base, $derived, $max) = @_;
    return Type::Coercion->new(
        type_coercion_map => [ Str, sub { substr $_, 0, $max } ]
    );
};

Zobacz Typy parametryzacji W Typ :: Tiny :: Manual :: Biblioteki - daje Dość dobre wyjaśnienie i przykład tego, jak wykonywać sparametryzowane typy z podwoziem i przymusem.

Sprawdziłem powyższe prace w bieżącym Typ :: Tiny uwalnianie, a nawet wersje tak stare jak 0,006 (wydane maj 2013)! Jak to robisz w oryginalnym kodzie nigdy nie było zamierzonym użyciem coercion_generator i jestem zaskoczony, że kiedykolwiek pracował.


Ponadto, jeśli jesteś zainteresowany, dlaczego dostajesz ostrzeżenie o głębokim przymusu, jest to spowodowane faktem, że $type->coercion działa podobnie jak leniwy atrybut w Moo / Łoś, i nazywa Coderef, ale Coderef nazywa się $type->coercion.

4
tobyink 21 listopad 2020, 01:09